Imports System.Data.SqlClient
Imports Logic.NullableDateExtensions
Imports Logic.DateExtensions
Imports ReportingClass

Public Class DrivingExperience
    Inherits System.Web.UI.Page

    Private Sub Page_Load(sender As Object, e As EventArgs) Handles Me.Load
        Try

            If Not Page.IsPostBack Then
                If Not _HasVisited() Then
                    _Prefill()
                End If
                _LoadForm()
                _LoadLists()
            Else
                _SaveAll()
                Page.Validate()
                If Page.IsValid Then
                    Master.EnableNextPage()
                End If
            End If

        Catch ex As Exception
            Dim errorId = Logic.Error.Log(ex)
            Response.Redirect("/Error.aspx?id=" & errorId)
        End Try
    End Sub

    Private Sub btnAddAccident_Click(sender As Object, e As EventArgs) Handles rptAccidents.AddClick
        Try
            If _HasEnteredLastAccident() Then
                rptAccidents.TargetCount = Math.Max(rptAccidents.TargetCount, rptAccidents.Items.Count) + 1
            End If
            _LoadAccidentList()
        Catch ex As Exception
            Dim errorId = Logic.Error.Log(ex)
            Response.Redirect("/Error.aspx?id=" & errorId)
        End Try
    End Sub

    Protected Sub btnRemoveAccident_Click(sender As Object, e As EventArgs)
        Try
            
            rptAccidents.TargetCount = Math.Max(rptAccidents.TargetCount, rptAccidents.Items.Count) - 1

            Dim btnRemove = DirectCast(sender, Button)
            Dim item = DirectCast(btnRemove.Parent, RepeaterItem)
            Dim hidId = DirectCast(item.FindControl("hidAccidentId"), HiddenField)

            _RemoveAccident(CInt(hidId.Value))
            _LoadAccidentList()

        Catch ex As Exception
            Dim errorId = Logic.Error.Log(ex)
            Response.Redirect("/Error.aspx?id=" & errorId)
        End Try
    End Sub

    Private Sub btnAddLicense_Click(sender As Object, e As EventArgs) Handles rptLicenses.AddClick
        Try
            If _HasEnteredLastLicense() Then
                rptLicenses.TargetCount = Math.Max(rptLicenses.TargetCount, rptLicenses.Items.Count) + 1
            End If
            _LoadLicenseList()
        Catch ex As Exception
            Dim errorId = Logic.Error.Log(ex)
            Response.Redirect("/Error.aspx?id=" & errorId)
        End Try
    End Sub

    Protected Sub btnRemoveLicense_Click(sender As Object, e As EventArgs)
        Try
            
            rptLicenses.TargetCount = Math.Max(rptLicenses.TargetCount, rptLicenses.Items.Count) - 1

            Dim btnRemove = DirectCast(sender, Button)
            Dim item = DirectCast(btnRemove.Parent, RepeaterItem)
            Dim hidId = DirectCast(item.FindControl("hidLicenseId"), HiddenField)

            _RemoveLicense(CInt(hidId.Value))
            _LoadLicenseList()

        Catch ex As Exception
            Dim errorId = Logic.Error.Log(ex)
            Response.Redirect("/Error.aspx?id=" & errorId)
        End Try
    End Sub

    Private Sub btnAddVehicle_Click(sender As Object, e As EventArgs) Handles rptVehicles.AddClick
        Try
            If _HasEnteredLastVehicle() Then
                rptVehicles.TargetCount = Math.Max(rptVehicles.TargetCount, rptVehicles.Items.Count) + 1
            End If
            _LoadVehicleList()
        Catch ex As Exception
            Dim errorId = Logic.Error.Log(ex)
            Response.Redirect("/Error.aspx?id=" & errorId)
        End Try
    End Sub

    Protected Sub btnRemoveVehicle_Click(sender As Object, e As EventArgs)
        Try
            
            rptVehicles.TargetCount = Math.Max(rptVehicles.TargetCount, rptVehicles.Items.Count) - 1

            Dim btnRemove = DirectCast(sender, Button)
            Dim item = DirectCast(btnRemove.Parent, RepeaterItem)
            Dim hidId = DirectCast(item.FindControl("hidVehicleId"), HiddenField)

            _RemoveVehicle(CInt(hidId.Value))
            _LoadVehicleList()

        Catch ex As Exception
            Dim errorId = Logic.Error.Log(ex)
            Response.Redirect("/Error.aspx?id=" & errorId)
        End Try
    End Sub

    Private Sub btnAddViolation_Click(sender As Object, e As EventArgs) Handles rptViolations.AddClick
        Try
            If _HasEnteredLastViolation() Then
                rptViolations.TargetCount = Math.Max(rptViolations.TargetCount, rptViolations.Items.Count) + 1
            End If
            _LoadViolationList()
        Catch ex As Exception
            Dim errorId = Logic.Error.Log(ex)
            Response.Redirect("/Error.aspx?id=" & errorId)
        End Try
    End Sub

    Protected Sub btnRemoveViolation_Click(sender As Object, e As EventArgs)
        Try
            
            rptViolations.TargetCount = Math.Max(rptViolations.TargetCount, rptViolations.Items.Count) - 1

            Dim btnRemove = DirectCast(sender, Button)
            Dim item = DirectCast(btnRemove.Parent, RepeaterItem)
            Dim hidId = DirectCast(item.FindControl("hidViolationId"), HiddenField)

            _RemoveViolation(CInt(hidId.Value))
            _LoadViolationList()

        Catch ex As Exception
            Dim errorId = Logic.Error.Log(ex)
            Response.Redirect("/Error.aspx?id=" & errorId)
        End Try
    End Sub

#Region "Loading internals"

    Private Sub _LoadForm()
        Using connection As New SqlConnection(Logic.Database.connectionString)
            connection.Open()

            Dim cmd As New SqlCommand("
                SELECT hasBeenDeniedLicense, licenseDeniedExplanation, 
                    hasHadLicenseRevoked, licenseRevokedExplanation,
                    hasHadAccidents, hasHadConvictions
                FROM web_DriverApplication WHERE id=@appId",
                connection)
            cmd.Parameters.AddWithValue("appId", Master.app.id)
            Dim dReader = cmd.ExecuteReader()
            dReader.Read()

            ynLicenseDenied.Checked = Logic.Conversion.ToNullableBoolean(dReader("hasBeenDeniedLicense"))
            ynLicenseRevoked.Checked = Logic.Conversion.ToNullableBoolean(dReader("hasHadLicenseRevoked"))
            ynThreeYearsAccidents.Checked = Logic.Conversion.ToNullableBoolean(dReader("hasHadAccidents"))
            ynThreeYearsConvictions.Checked = Logic.Conversion.ToNullableBoolean(dReader("hasHadConvictions"))
            txtLicenseDeniedExplanation.Text = Logic.Conversion.ToString(dReader("licenseDeniedExplanation"))
            txtLicenseRevokedExplanation.Text = Logic.Conversion.ToString(dReader("licenseRevokedExplanation"))

        End Using
    End Sub

    Private Sub _LoadLists()
        _LoadAccidentList()
        _LoadLicenseList()
        _LoadVehicleList()
        _LoadViolationList()
    End Sub

    Private Sub _LoadAccidentList()
        Using connection As New SqlConnection(Logic.Database.connectionString)
            connection.Open()

            Dim cmdCount As New SqlCommand(
                "SELECT COUNT(id) FROM web_DriverApplicationAccidents WHERE AppId=@appId",
                connection)
            cmdCount.Parameters.AddWithValue("appId", Master.app.id)
            Dim count = CInt(cmdCount.ExecuteScalar())
            count = Math.Max(count, rptAccidents.TargetCount)

            Dim cmdAccidents As New SqlCommand("
                SELECT * FROM web_DriverApplicationAccidents
                WHERE AppId=@appId",
                connection)
            cmdAccidents.Parameters.AddWithValue("appId", Master.app.id)

            Dim dummy As New List(Of Integer)
            For i = 1 To count : dummy.Add(i) : Next
            rptAccidents.DataSource = dummy
            rptAccidents.DataBind()

            Dim dReader = cmdAccidents.ExecuteReader()
            For each item As RepeaterItem In rptAccidents.Items
                Dim hidId As HiddenField = item.FindControl("hidAccidentId")
                Dim txtAccidentDate As TextBox = item.FindControl("txtAccidentDate")
                Dim txtAccidentNature As TextBox = item.FindControl("txtAccidentNature")
                Dim txtAccidentConsequences As TextBox = item.FindControl("txtAccidentConsequences")
                Dim txtAccidentComments As TextBox = item.FindControl("txtAccidentComments")

                If dReader.Read() Then
                    hidId.Value = dReader("id")
                    txtAccidentDate.Text = Logic.Conversion.ToDate(dReader("Date")).FormatForHtml5()
                    txtAccidentNature.Text = dReader("Nature")
                    txtAccidentConsequences.Text = dReader("Consequence")
                    txtAccidentComments.Text = dReader("Comments")
                End If
            Next

        End Using
    End Sub

    Private Sub _LoadLicenseList()
        Using connection As New SqlConnection(Logic.Database.connectionString)
            connection.Open()

            Dim cmdCount As New SqlCommand(
                "SELECT COUNT(id) FROM web_DriverApplicationLicenses WHERE AppId=@appId",
                connection)
            cmdCount.Parameters.AddWithValue("appId", Master.app.id)
            Dim count = CInt(cmdCount.ExecuteScalar())
            count = Math.Max(count, rptLicenses.TargetCount)

            Dim cmdLicenses As New SqlCommand("
                SELECT * FROM web_DriverApplicationLicenses
                WHERE AppId=@appId",
                connection)
            cmdLicenses.Parameters.AddWithValue("appId", Master.app.id)

            Dim dummy As New List(Of Integer)
            For i = 1 To count : dummy.Add(i) : Next
            rptLicenses.DataSource = dummy
            rptLicenses.DataBind()

            ' We lose list of states after repeater rebind.
            ' This refills the states so that we can set them back.
            For Each item As RepeaterItem In rptLicenses.Items
                Dim ddlLicenseState As StatePicker = item.FindControl("ddlLicenseState")
                ddlLicenseState.Rebind()
            Next

            Dim dReader = cmdLicenses.ExecuteReader()
            For each item As RepeaterItem In rptLicenses.Items
                Dim hidId As HiddenField = item.FindControl("hidLicenseId")
                Dim txtLicenseNumber As TextBox = item.FindControl("txtLicenseNumber")
                Dim ddlLicenseState As StatePicker = item.FindControl("ddlLicenseState")
                Dim txtLicenseType As TextBox = item.FindControl("txtLicenseType")
                Dim txtLicenseExpires As TextBox = item.FindControl("txtLicenseExpires")
                Dim ynCDL As YesNoPicker = item.FindControl("ynCDL")
                Dim chkN As CheckBox = item.FindControl("chkN")
                Dim chkS As CheckBox = item.FindControl("chkS")
                Dim chkH As CheckBox = item.FindControl("chkH")
                Dim chkX As CheckBox = item.FindControl("chkX")
                Dim chkT As CheckBox = item.FindControl("chkT")
                Dim chkP As CheckBox = item.FindControl("chkP")
                Dim txtLicenseRestrictions As TextBox = item.FindControl("txtLicenseRestrictions")

                If dReader.Read() Then
                    hidId.Value = dReader("id")
                    txtLicenseNumber.Text = dReader("Number")
                    ddlLicenseState.SelectedValue = dReader("State")
                    txtLicenseType.Text = dReader("Type")
                    txtLicenseExpires.Text = Logic.Conversion.ToDate(dReader("Expires")).FormatForHtml5()
                    txtLicenseRestrictions.Text = dReader("Restrictions")

                    Dim endorsements = CStr(dReader("Endorsements"))
                    ynCDL.Checked = endorsements.Contains("/CDL/")
                    chkN.Checked = endorsements.Contains("/N/")
                    chkS.Checked = endorsements.Contains("/S/")
                    chkH.Checked = endorsements.Contains("/H/")
                    chkX.Checked = endorsements.Contains("/X/")
                    chkT.Checked = endorsements.Contains("/T/")
                    chkP.Checked = endorsements.Contains("/P/")

                    If Logic.Conversion.ToBoolean(dReader("isCDLEmpty")) = True Then
                        ynCDL.Checked = Nothing
                    End If
                End If
            Next

        End Using
    End Sub

    Private Sub _LoadVehicleList()
        Using connection As New SqlConnection(Logic.Database.connectionString)
            connection.Open()

            Dim cmdCount As New SqlCommand(
                "SELECT COUNT(id) FROM web_DriverApplicationVehicles WHERE AppId=@appId",
                connection)
            cmdCount.Parameters.AddWithValue("appId", Master.app.id)
            Dim count = CInt(cmdCount.ExecuteScalar())
            count = Math.Max(count, rptVehicles.TargetCount)

            Dim cmdVehicles As New SqlCommand("
                SELECT * FROM web_DriverApplicationVehicles
                WHERE AppId=@appId",
                connection)
            cmdVehicles.Parameters.AddWithValue("appId", Master.app.id)

            Dim dummy As New List(Of Integer)
            For i = 1 To count : dummy.Add(i) : Next
            rptVehicles.DataSource = dummy
            rptVehicles.DataBind()

            Dim dReader = cmdVehicles.ExecuteReader()
            For each item As RepeaterItem In rptVehicles.Items
                Dim hidId As HiddenField = item.FindControl("hidVehicleId")
                Dim ddlEquipmentType As DropDownList = item.FindControl("ddlEquipmentType")
                Dim txtEquipmentType As TextBox = item.FindControl("txtEquipmentType")
                Dim txtEquipmentYears As TextBox = item.FindControl("txtEquipmentYears")
                Dim txtEquipmentMiles As TextBox = item.FindControl("txtEquipmentMiles")
                Dim ynRequiredCDL As YesNoPicker = item.FindControl("ynRequiredCDL")
                Dim litId_ddlEquipmentType As Literal = item.FindControl("litId_ddlEquipmentType")

                litId_ddlEquipmentType.Text = ddlEquipmentType.ClientId

                If dReader.Read() Then

                    hidId.Value = dReader("id")
                    txtEquipmentYears.Text = dReader("Years")
                    txtEquipmentMiles.Text = dReader("Miles")
                    ynRequiredCDL.Checked = Logic.Conversion.ToNullableBoolean(dReader("RequiredCDL"))

                    Dim EquipmentType = Logic.Conversion.ToString(dReader("Type"))
                    If EquipmentType.Length Then
                        If ddlEquipmentType.Items.FindByValue(EquipmentType) IsNot Nothing Then
                            ddlEquipmentType.SelectedValue = EquipmentType
                        Else
                            ddlEquipmentType.SelectedValue = "Other"
                            txtEquipmentType.Text = EquipmentType
                        End If
                    End If

                End If
            Next

        End Using
    End Sub

    Private Sub _LoadViolationList()
        Using connection As New SqlConnection(Logic.Database.connectionString)
            connection.Open()

            Dim cmdCount As New SqlCommand(
                "SELECT COUNT(id) FROM web_DriverApplicationConvictions WHERE AppId=@appId",
                connection)
            cmdCount.Parameters.AddWithValue("appId", Master.app.id)
            Dim count = CInt(cmdCount.ExecuteScalar())
            count = Math.Max(count, rptViolations.TargetCount)

            Dim cmdViolations As New SqlCommand("
                SELECT * FROM web_DriverApplicationConvictions
                WHERE AppId=@appId",
                connection)
            cmdViolations.Parameters.AddWithValue("appId", Master.app.id)

            Dim dummy As New List(Of Integer)
            For i = 1 To count : dummy.Add(i) : Next
            rptViolations.DataSource = dummy
            rptViolations.DataBind()

            ' We lose list of states after repeater rebind.
            ' This refills the states so that we can set them back.
            For Each item As RepeaterItem In rptViolations.Items
                Dim ddlConvictionState As StatePicker = item.FindControl("ddlConvictionState")
                ddlConvictionState.Rebind()
            Next

            Dim dReader = cmdViolations.ExecuteReader()
            For each item As RepeaterItem In rptViolations.Items
                Dim hidId As HiddenField = item.FindControl("hidViolationId")
                Dim txtConvictionDate As TextBox = item.FindControl("txtConvictionDate")
                Dim ddlConvictionState As StatePicker = item.FindControl("ddlConvictionState")
                Dim txtConvictionCharge As TextBox = item.FindControl("txtConvictionCharge")
                Dim txtConvictionPenalty As TextBox = item.FindControl("txtConvictionPenalty")

                If dReader.Read() Then
                    hidId.Value = dReader("id")
                    txtConvictionDate.Text = Logic.Conversion.ToDate(dReader("Date")).FormatForHtml5()
                    ddlConvictionState.SelectedValue = dReader("State")
                    txtConvictionCharge.Text = dReader("Charge")
                    txtConvictionPenalty.Text = dReader("Penalty")
                End If
            Next

        End Using
    End Sub

    Private Sub _Prefill()
        '
    End Sub

#End Region

#Region "Saving internals"

    Private Sub _SaveAll()
        Using connection As New SqlConnection(Logic.Database.connectionString)
            connection.Open()
            Using transaction = connection.BeginTransaction()
                _SaveForm(connection, transaction)
                _SaveLists(connection, transaction)
                _SaveDocument(connection, transaction)
                transaction.Commit()
            End Using
        End Using
    End Sub

    Private Sub _SaveForm(connection As SqlConnection, transaction As SqlTransaction)

        Dim licenseDenied = ynLicenseDenied.Checked
        Dim licenseRevoked = ynLicenseRevoked.Checked
        Dim hadAccidents = ynThreeYearsAccidents.Checked
        Dim hadConvictions = ynThreeYearsConvictions.Checked

        Dim cmdSave As New SqlCommand("
            UPDATE web_DriverApplication
            SET hasBeenDeniedLicense=@hasBeenDeniedLicense, licenseDeniedExplanation=@licenseDeniedExplanation,
                hasHadLicenseRevoked=@hasHadLicenseRevoked, licenseRevokedExplanation=@licenseRevokedExplanation,
                hasHadConvictions=@hasHadConvictions, hasHadAccidents=@hasHadAccidents
            WHERE id=@appId",
            connection, transaction)

        With cmdSave.Parameters
            .AddWithValue("appId", Master.app.id)
            .AddWithValue("hasBeenDeniedLicense", If(licenseDenied.HasValue, licenseDenied.Value, DBNull.Value))
            .AddWithValue("licenseDeniedExplanation", If(licenseDenied.HasValue, txtLicenseDeniedExplanation.Text, DBNull.Value))
            .AddWithValue("hasHadLicenseRevoked", If(licenseRevoked.HasValue, licenseRevoked.Value, DBNull.Value))
            .AddWithValue("licenseRevokedExplanation", If(licenseRevoked.HasValue, txtLicenseRevokedExplanation.Text, DBNull.Value))
            .AddWithValue("hasHadAccidents", If(hadAccidents.HasValue, hadAccidents.Value, DBNull.Value))
            .AddWithValue("hasHadConvictions", If(hadConvictions.HasValue, hadConvictions.Value, DBNull.Value))
        End With

        cmdSave.ExecuteNonQuery()

    End Sub

    Private Sub _SaveLists(connection As SqlConnection, transaction As SqlTransaction)
        _SaveAccidentList(connection, transaction)
        _SaveLicenseList(connection, transaction)
        _SaveVehicleList(connection, transaction)
        _SaveViolationList(connection, transaction)
    End Sub

    Private Sub _SaveAccidentList(connection As SqlConnection, transaction As SqlTransaction)
        
        Dim cmdDelete As New SqlCommand(
            "DELETE FROM web_DriverApplicationAccidents WHERE AppId=@appId",
            connection, transaction)
        cmdDelete.Parameters.AddWithValue("appId", Master.app.id)
        cmdDelete.ExecuteNonQuery()

        Dim cmdSave As New SqlCommand("
            INSERT INTO web_DriverApplicationAccidents
            (AppId, [Date], Nature, Consequence, Comments)
            VALUES (@appId, @date, @nature, @consequence, @comments);
            SELECT @@IDENTITY;",
            connection, transaction)
        With cmdSave.Parameters
            .AddWithValue("appId", Master.app.id)
            .Add(New SqlParameter("date", SqlDbType.Date))
            .Add(New SqlParameter("nature", SqlDbType.VarChar))
            .Add(New SqlParameter("consequence", SqlDbType.VarChar))
            .Add(New SqlParameter("comments", SqlDbType.VarChar))
        End With

        For Each item As RepeaterItem In rptAccidents.Items
            Dim hidId As HiddenField = item.FindControl("hidAccidentId")
            Dim txtAccidentDate As TextBox = item.FindControl("txtAccidentDate")
            Dim txtAccidentNature As TextBox = item.FindControl("txtAccidentNature")
            Dim txtAccidentConsequences As TextBox = item.FindControl("txtAccidentConsequences")
            Dim txtAccidentComments As TextBox = item.FindControl("txtAccidentComments")
            
            cmdSave.Parameters("date").Value = Logic.Conversion.ToDate(txtAccidentDate.Text).Clip()
            cmdSave.Parameters("nature").Value = txtAccidentNature.Text
            cmdSave.Parameters("consequence").Value = txtAccidentConsequences.Text
            cmdSave.Parameters("comments").Value = txtAccidentComments.Text

            hidId.Value = cmdSave.ExecuteScalar()
        Next

    End Sub

    Private Sub _SaveLicenseList(connection As SqlConnection, transaction As SqlTransaction)
        
        Dim cmdDelete As New SqlCommand(
            "DELETE FROM web_DriverApplicationLicenses WHERE AppId=@appId",
            connection, transaction)
        cmdDelete.Parameters.AddWithValue("appId", Master.app.id)
        cmdDelete.ExecuteNonQuery()

        Dim cmdSave As New SqlCommand("
            INSERT INTO web_DriverApplicationLicenses
            (AppId, Number, State, Type, Expires, Endorsements, Restrictions, isCDLEmpty)
            VALUES (@appId, @number, @state, @type, @expires, @endorsements, @restrictions, @isCDLEmpty);
            SELECT @@IDENTITY;",
            connection, transaction)
        With cmdSave.Parameters
            .AddWithValue("appId", Master.app.id)
            .Add(New SqlParameter("number", SqlDbType.VarChar))
            .Add(New SqlParameter("state", SqlDbType.VarChar))
            .Add(New SqlParameter("type", SqlDbType.VarChar))
            .Add(New SqlParameter("expires", SqlDbType.Date))
            .Add(New SqlParameter("endorsements", SqlDbType.VarChar))
            .Add(New SqlParameter("restrictions", SqlDbType.VarChar))
            .Add(New SqlParameter("isCDLEmpty", SqlDbType.Bit))
        End With

        For Each item As RepeaterItem In rptLicenses.Items
            Dim hidId As HiddenField = item.FindControl("hidLicenseId")
            Dim txtLicenseNumber As TextBox = item.FindControl("txtLicenseNumber")
            Dim ddlLicenseState As StatePicker = item.FindControl("ddlLicenseState")
            Dim txtLicenseType As TextBox = item.FindControl("txtLicenseType")
            Dim txtLicenseExpires As TextBox = item.FindControl("txtLicenseExpires")
            Dim ynCDL As YesNoPicker = item.FindControl("ynCDL")
            Dim chkN As CheckBox = item.FindControl("chkN")
            Dim chkS As CheckBox = item.FindControl("chkS")
            Dim chkH As CheckBox = item.FindControl("chkH")
            Dim chkX As CheckBox = item.FindControl("chkX")
            Dim chkT As CheckBox = item.FindControl("chkT")
            Dim chkP As CheckBox = item.FindControl("chkP")
            Dim txtLicenseRestrictions As TextBox = item.FindControl("txtLicenseRestrictions")
            
            cmdSave.Parameters("number").Value = txtLicenseNumber.Text
            cmdSave.Parameters("state").Value = ddlLicenseState.SelectedValue
            cmdSave.Parameters("type").Value = txtLicenseType.Text
            cmdSave.Parameters("expires").Value = Logic.Conversion.ToDate(txtLicenseExpires.Text).Clip()
            cmdSave.Parameters("endorsements").Value = If(ynCDL.Checked, "/CDL", "") & If(chkN.Checked, "/N", "") & If(chkS.Checked, "/S", "") & If(chkH.Checked, "/H", "") & If(chkX.Checked, "/X", "") & If(chkT.Checked, "/T", "") & If(chkP.Checked, "/P", "") & "/"
            cmdSave.Parameters("restrictions").Value = txtLicenseRestrictions.Text
            cmdSave.Parameters("isCDLEmpty").Value = Not ynCDL.Checked.HasValue
            hidId.Value = cmdSave.ExecuteScalar()
        Next

        ' We want to do another save for the stuff that pulls from first license
        If rptLicenses.Items.Count > 0 Then
            Dim item As RepeaterItem = rptLicenses.Items(0)
            Dim hidId As HiddenField = item.FindControl("hidLicenseId")
            Dim txtLicenseNumber As TextBox = item.FindControl("txtLicenseNumber")
            Dim ddlLicenseState As StatePicker = item.FindControl("ddlLicenseState")
            Dim txtLicenseType As TextBox = item.FindControl("txtLicenseType")
            Dim txtLicenseExpires As TextBox = item.FindControl("txtLicenseExpires")
            Dim ynCDL As YesNoPicker = item.FindControl("ynCDL")
            Dim chkN As CheckBox = item.FindControl("chkN")
            Dim chkS As CheckBox = item.FindControl("chkS")
            Dim chkH As CheckBox = item.FindControl("chkH")
            Dim chkX As CheckBox = item.FindControl("chkX")
            Dim chkT As CheckBox = item.FindControl("chkT")
            Dim chkP As CheckBox = item.FindControl("chkP")
            Dim txtLicenseRestrictions As TextBox = item.FindControl("txtLicenseRestrictions")

            Dim cmdSaveFirst As New SqlCommand("
                UPDATE web_DriverApplication
                SET license1Number=@number, license1State=@state, 
                    license1Endorsements=@endorsements, license1Restrictions=@restrictions,
                    license1Expiration=@expiration, license1Class=@class
                WHERE id=@appId",
                connection, transaction)
            With cmdSaveFirst.Parameters
                .AddWithValue("appId", Master.app.id)
                .AddWithValue("number", txtLicenseNumber.Text)
                .AddWithValue("state", ddlLicenseState.SelectedValue)
                .AddWithValue("class", txtLicenseType.Text)
                .AddWithValue("expiration", Logic.Conversion.ToDate(txtLicenseExpires.Text).Clip())
                .AddWithValue("endorsements", If(ynCDL.Checked, "/CDL", "") & If(chkN.Checked, "/N", "") & If(chkS.Checked, "/S", "") & If(chkH.Checked, "/H", "") & If(chkX.Checked, "/X", "") & If(chkT.Checked, "/T", "") & If(chkP.Checked, "/P", "") & "/")
                .AddWithValue("restrictions", txtLicenseRestrictions.Text)
            End With
            cmdSaveFirst.ExecuteNonQuery()

        End If

    End Sub

    Private Sub _SaveVehicleList(connection As SqlConnection, transaction As SqlTransaction)
        
        Dim cmdDelete As New SqlCommand(
            "DELETE FROM web_DriverApplicationVehicles WHERE AppId=@appId",
            connection, transaction)
        cmdDelete.Parameters.AddWithValue("appId", Master.app.id)
        cmdDelete.ExecuteNonQuery()

        Dim cmdSave As New SqlCommand("
            INSERT INTO web_DriverApplicationVehicles
            (AppId, Type, Years, Miles, RequiredCDL)
            VALUES (@appId, @type, @years, @miles, @cdl);
            SELECT @@IDENTITY;",
            connection, transaction)
        With cmdSave.Parameters
            .AddWithValue("appId", Master.app.id)
            .Add(New SqlParameter("type", SqlDbType.VarChar))
            .Add(New SqlParameter("years", SqlDbType.Int))
            .Add(New SqlParameter("miles", SqlDbType.Int))
            .Add(New SqlParameter("cdl", SqlDbType.Bit)).IsNullable = True
        End With

        For Each item As RepeaterItem In rptVehicles.Items
            Dim hidId As HiddenField = item.FindControl("hidVehicleId")
            Dim ddlEquipmentType As DropDownList = item.FindControl("ddlEquipmentType")
            Dim txtEquipmentType As TextBox = item.FindControl("txtEquipmentType")
            Dim txtEquipmentYears As TextBox = item.FindControl("txtEquipmentYears")
            Dim txtEquipmentMiles As TextBox = item.FindControl("txtEquipmentMiles")
            Dim ynRequiredCDL As YesNoPicker = item.FindControl("ynRequiredCDL")

            Dim EquipmentType = ddlEquipmentType.SelectedValue
            If EquipmentType = "Other" Then
                EquipmentType = txtEquipmentType.Text
            End If

            Dim cdl = ynRequiredCDL.Checked
            
            cmdSave.Parameters("type").Value = EquipmentType
            cmdSave.Parameters("years").Value = Logic.Conversion.ToInteger(txtEquipmentYears.Text)
            cmdSave.Parameters("miles").Value = Logic.Conversion.ToInteger(txtEquipmentMiles.Text)
            cmdSave.Parameters("cdl").Value = If(cdl.HasValue, cdl.Value, DBNull.Value)

            hidId.Value = cmdSave.ExecuteScalar()
        Next

    End Sub

    Private Sub _SaveViolationList(connection As SqlConnection, transaction As SqlTransaction)
        
        Dim cmdDelete As New SqlCommand(
            "DELETE FROM web_DriverApplicationConvictions WHERE AppId=@appId",
            connection, transaction)
        cmdDelete.Parameters.AddWithValue("appId", Master.app.id)
        cmdDelete.ExecuteNonQuery()

        Dim cmdSave As New SqlCommand("
            INSERT INTO web_DriverApplicationConvictions
            (AppId, [Date], [State], Charge, Penalty)
            VALUES (@appId, @date, @state, @charge, @penalty);
            SELECT @@IDENTITY;",
            connection, transaction)
        With cmdSave.Parameters
            .AddWithValue("appId", Master.app.id)
            .Add(New SqlParameter("date", SqlDbType.VarChar))
            .Add(New SqlParameter("state", SqlDbType.VarChar))
            .Add(New SqlParameter("charge", SqlDbType.VarChar))
            .Add(New SqlParameter("penalty", SqlDbType.VarChar))
        End With

        For Each item As RepeaterItem In rptViolations.Items
            Dim hidId As HiddenField = item.FindControl("hidViolationId")
            Dim txtConvictionDate As TextBox = item.FindControl("txtConvictionDate")
            Dim ddlConvictionState As StatePicker = item.FindControl("ddlConvictionState")
            Dim txtConvictionCharge As TextBox = item.FindControl("txtConvictionCharge")
            Dim txtConvictionPenalty As TextBox = item.FindControl("txtConvictionPenalty")
            
            cmdSave.Parameters("date").Value = Logic.Conversion.ToDate(txtConvictionDate.Text).Clip()
            cmdSave.Parameters("state").Value = ddlConvictionState.SelectedValue
            cmdSave.Parameters("charge").Value = txtConvictionCharge.Text
            cmdSave.Parameters("penalty").Value = txtConvictionPenalty.Text

            hidId.Value = cmdSave.ExecuteScalar()
        Next

    End Sub

    Private Sub _SaveDocument(connection As SqlConnection, transaction As SqlTransaction)
        Dim ReportDataSet As New dsAppDrivingExperience
        Dim ReportTableAdapter As New TransactionalAppDrivingExperienceTableAdapter
        ReportTableAdapter.SetConnection(connection, transaction)
        ReportTableAdapter.Fill(ReportDataSet.AppDrivingExperienceDataTable, Master.app.id)

        Using Report As New crptAppDrivingExperience
            Report.SetDataSource(ReportDataSet)
            Dim rawData = Reporting.StreamToByteArray(Report)

            Dim cmdSave = "
                UPDATE web_DriverApplicationPdf SET pageTitle=@pageTitle, pdfData=@pdfData, pdfDataSize=@pdfDataSize
                WHERE appId=@appId AND pageFileName=@pageFileName;
                IF @@ROWCOUNT = 0 BEGIN
                    INSERT INTO web_DriverApplicationPdf (appId, pageTitle, pageFileName, pdfData, pdfDataSize)
                    VALUES (@appId, @pageTitle, @pageFileName, @pdfData, @pdfDataSize);
                END"
            Dim cmd As New SqlCommand(cmdSave, connection, transaction)
            cmd.Parameters.AddWithValue("appId", Master.app.id)
            cmd.Parameters.AddWithValue("pageTitle", Master.CurrentTitle)
            cmd.Parameters.AddWithValue("pageFileName", Master.CurrentPage)
            cmd.Parameters.AddWithValue("pdfData", rawData)
            cmd.Parameters.AddWithValue("pdfDataSize", rawData.Length)
            cmd.ExecuteNonQuery()
        End Using
    End Sub

#End Region

#Region "Other internals"

    Private Function _HasEnteredLastAccident() As Boolean
        Dim count = rptAccidents.Items.Count
        If count = 0 Then
            Return True
        Else
            Dim item As RepeaterItem = rptAccidents.Items(count - 1)
            Dim txtAccidentDate As TextBox = item.FindControl("txtAccidentDate")
            Return txtAccidentDate.Text.Length > 0
        End If
    End Function

    Private Function _HasEnteredLastLicense() As Boolean
        Dim count = rptLicenses.Items.Count
        If count = 0 Then
            Return True
        Else
            Dim item As RepeaterItem = rptLicenses.Items(count - 1)
            If CType(item.FindControl("txtLicenseNumber"), TextBox).Text.Length = 0 Then Return False
            If CType(item.FindControl("ynCDL"), YesNoPicker).Checked.HasValue = False Then Return False
            Return True
        End If
    End Function

    Private Function _HasEnteredLastVehicle() As Boolean
        Dim count = rptVehicles.Items.Count
        If count = 0 Then
            Return True
        Else
            Dim item As RepeaterItem = rptVehicles.Items(count - 1)
            Dim ddlEquipmentType As DropDownList = item.FindControl("ddlEquipmentType")
            Dim txtEquipmentType As TextBox = item.FindControl("txtEquipmentType")
            If ddlEquipmentType.Text = "Other" And txtEquipmentType.Text.Length = 0 Then
                Return False
            End If
            Return True
        End If
    End Function

    Private Function _HasEnteredLastViolation() As Boolean
        Dim count = rptViolations.Items.Count
        If count = 0 Then
            Return True
        Else
            Dim item As RepeaterItem = rptViolations.Items(count - 1)
            Dim txtConvictionDate As TextBox = item.FindControl("txtConvictionDate")
            Return txtConvictionDate.Text.Length > 0
        End If
    End Function

    Private Function _HasVisited() As Boolean
        Using connection As New SqlConnection(Logic.Database.connectionString)
            connection.Open()
            Dim cmd As New SqlCommand(
                "SELECT hasHadConvictions FROM web_DriverApplication WHERE id=@appId",
                connection)
            cmd.Parameters.AddWithValue("appId", Master.app.id)
            Return TypeOf cmd.ExecuteScalar() IsNot DBNull
        End Using
    End Function

    Private Sub _RemoveAccident(itemId As Integer)
        Using connection As New SqlConnection(Logic.Database.connectionString)
            connection.Open()
            Dim cmd As New SqlCommand(
                "DELETE FROM web_DriverApplicationAccidents WHERE id=@itemId",
                connection)
            cmd.Parameters.AddWithValue("itemId", itemId)
            cmd.ExecuteNonQuery()
        End Using
    End Sub

    Private Sub _RemoveLicense(itemId As Integer)
        Using connection As New SqlConnection(Logic.Database.connectionString)
            connection.Open()
            Dim cmd As New SqlCommand(
                "DELETE FROM web_DriverApplicationLicenses WHERE id=@itemId",
                connection)
            cmd.Parameters.AddWithValue("itemId", itemId)
            cmd.ExecuteNonQuery()
        End Using
    End Sub

    Private Sub _RemoveVehicle(itemId As Integer)
        Using connection As New SqlConnection(Logic.Database.connectionString)
            connection.Open()
            Dim cmd As New SqlCommand(
                "DELETE FROM web_DriverApplicationVehicles WHERE id=@itemId",
                connection)
            cmd.Parameters.AddWithValue("itemId", itemId)
            cmd.ExecuteNonQuery()
        End Using
    End Sub

    Private Sub _RemoveViolation(itemId As Integer)
        Using connection As New SqlConnection(Logic.Database.connectionString)
            connection.Open()
            Dim cmd As New SqlCommand(
                "DELETE FROM web_DriverApplicationConvictions WHERE id=@itemId",
                connection)
            cmd.Parameters.AddWithValue("itemId", itemId)
            cmd.ExecuteNonQuery()
        End Using
    End Sub

#End Region

End Class