Imports System.Data.SqlClient
Imports Logic.NullableDateExtensions
Imports Logic.DateExtensions
Imports ReportingClass

Public Class Unemployment
    Inherits System.Web.UI.Page


    Private Sub Page_Load(sender As Object, e As EventArgs) Handles Me.Load
        Try

            If Not Page.IsPostBack Then
                If Not _HasVisited() Then
                    _Prefill()
                End If
                _LoadForm()
                _LoadLists()
            Else
                _SaveAll()
                Page.Validate()
                If Page.IsValid Then
                    Master.EnableNextPage()
                End If
            End If

        Catch ex As Exception
            Dim errorId = Logic.Error.Log(ex)
            Response.Redirect("/Error.aspx?id=" & errorId)
        End Try
    End Sub

    Private Sub btnAddUnemp_Click(sender As Object, e As EventArgs) Handles rptUnemp.AddClick
        Try
            If _HasEnteredLastUnemp() Then
                rptUnemp.TargetCount = Math.Max(rptUnemp.TargetCount, rptUnemp.Items.Count) + 1
            End If
            _LoadUnempList()
        Catch ex As Exception
            Dim errorId = Logic.Error.Log(ex)
            Response.Redirect("/Error.aspx?id=" & errorId)
        End Try
    End Sub

    Protected Sub btnRemoveUnemp_Click(sender As Object, e As EventArgs)
        Try

            rptUnemp.TargetCount = Math.Max(rptUnemp.TargetCount, rptUnemp.Items.Count) - 1

            Dim btnRemove = DirectCast(sender, Button)
            Dim item = DirectCast(btnRemove.Parent, RepeaterItem)
            Dim hidId = DirectCast(item.FindControl("hidUnempId"), HiddenField)

            _RemoveUnemp(CInt(hidId.Value))
            _LoadUnempList()

        Catch ex As Exception
            Dim errorId = Logic.Error.Log(ex)
            Response.Redirect("/Error.aspx?id=" & errorId)
        End Try
    End Sub

#Region "Loading internals"

    Private Sub _LoadForm()
        Using connection As New SqlConnection(Logic.Database.ConnectionString)
            connection.Open()

            Dim cmd As New SqlCommand("
                SELECT hasHadUnemp
                FROM web_DriverApplication WHERE id=@appId",
                connection)
            cmd.Parameters.AddWithValue("appId", Master.app.id)
            Dim dReader = cmd.ExecuteReader()
            dReader.Read()

            'ynLicenseDenied.Checked = Logic.Conversion.ToNullableBoolean(dReader("hasBeenDeniedLicense"))
            'ynLicenseRevoked.Checked = Logic.Conversion.ToNullableBoolean(dReader("hasHadLicenseRevoked"))
            'ynThreeYearsAccidents.Checked = Logic.Conversion.ToNullableBoolean(dReader("hasHadAccidents"))
            ynUnemployed.Checked = Logic.Conversion.ToNullableBoolean(dReader("hasHadUnemp"))
            'txtLicenseDeniedExplanation.Text = Logic.Conversion.ToString(dReader("licenseDeniedExplanation"))
            'txtLicenseRevokedExplanation.Text = Logic.Conversion.ToString(dReader("licenseRevokedExplanation"))

        End Using
    End Sub

    Private Sub _LoadLists()

        _LoadUnempList()
    End Sub



    Private Sub _LoadUnempList()
        Using connection As New SqlConnection(Logic.Database.ConnectionString)
            connection.Open()

            Dim cmdCount As New SqlCommand(
                "SELECT COUNT(id) FROM web_DriverApplicationUnemployment WHERE AppId=@appId",
                connection)
            cmdCount.Parameters.AddWithValue("appId", Master.app.id)
            Dim count = CInt(cmdCount.ExecuteScalar())
            count = Math.Max(count, rptUnemp.TargetCount)

            Dim cmdUnemp As New SqlCommand("
                SELECT * FROM web_DriverApplicationUnemployment
                WHERE AppId=@appId",
                connection)
            cmdUnemp.Parameters.AddWithValue("appId", Master.app.id)

            Dim dummy As New List(Of Integer)
            For i = 1 To count : dummy.Add(i) : Next
            rptUnemp.DataSource = dummy
            rptUnemp.DataBind()


            Dim dReader = cmdUnemp.ExecuteReader()
            For Each item As RepeaterItem In rptUnemp.Items
                Dim hidId As HiddenField = item.FindControl("hidUnempId")
                Dim txtStartDate As TextBox = item.FindControl("txtStartDate")
                Dim txtEndDate As TextBox = item.FindControl("txtEndDate")
                Dim txtComments As TextBox = item.FindControl("txtComments")

                If dReader.Read() Then
                    hidId.Value = dReader("id")
                    txtStartDate.Text = Logic.Conversion.ToDate(dReader("StartDate")).FormatForHtml5()
                    txtEndDate.Text = Logic.Conversion.ToDate(dReader("EndDate")).FormatForHtml5()
                    txtComments.Text = dReader("Comments")
                End If
            Next

        End Using
    End Sub

    Private Sub _Prefill()
        '
    End Sub

#End Region

#Region "Saving internals"

    Private Sub _SaveAll()
        Using connection As New SqlConnection(Logic.Database.ConnectionString)
            connection.Open()
            Using transaction = connection.BeginTransaction()
                _SaveForm(connection, transaction)
                _SaveLists(connection, transaction)
                _SaveDocument(connection, transaction)
                transaction.Commit()
            End Using
        End Using
    End Sub

    Private Sub _SaveForm(connection As SqlConnection, transaction As SqlTransaction)

        'Dim licenseDenied = ynLicenseDenied.Checked
        'Dim licenseRevoked = ynLicenseRevoked.Checked
        'Dim hadAccidents = ynThreeYearsAccidents.Checked
        Dim hadUnemp = ynUnemployed.Checked

        Dim cmdSave As New SqlCommand("
            UPDATE web_DriverApplication
            SET hasHadUnemp=@hasHadUnemp
            WHERE id=@appId",
            connection, transaction)

        With cmdSave.Parameters
            .AddWithValue("appId", Master.app.id)
            '.AddWithValue("hasBeenDeniedLicense", If(licenseDenied.HasValue, licenseDenied.Value, DBNull.Value))
            '.AddWithValue("licenseDeniedExplanation", If(licenseDenied.HasValue, txtLicenseDeniedExplanation.Text, DBNull.Value))
            '.AddWithValue("hasHadLicenseRevoked", If(licenseRevoked.HasValue, licenseRevoked.Value, DBNull.Value))
            '.AddWithValue("licenseRevokedExplanation", If(licenseRevoked.HasValue, txtLicenseRevokedExplanation.Text, DBNull.Value))
            '.AddWithValue("hasHadAccidents", If(hadAccidents.HasValue, hadAccidents.Value, DBNull.Value))
            .AddWithValue("hasHadUnemp", If(hadUnemp.HasValue, hadUnemp.Value, DBNull.Value))
        End With

        cmdSave.ExecuteNonQuery()

    End Sub

    Private Sub _SaveLists(connection As SqlConnection, transaction As SqlTransaction)
        _SaveUnempList(connection, transaction)
    End Sub


    Private Sub _SaveUnempList(connection As SqlConnection, transaction As SqlTransaction)

        Dim cmdDelete As New SqlCommand(
            "DELETE FROM web_DriverApplicationUnemployment WHERE AppId=@appId",
            connection, transaction)
        cmdDelete.Parameters.AddWithValue("appId", Master.app.id)
        cmdDelete.ExecuteNonQuery()

        Dim cmdSave As New SqlCommand("
            INSERT INTO web_DriverApplicationUnemployment
            (AppId, StartDate,EndDate, Comments)
            VALUES (@appId, @StartDate,@EndDate, @Comments);
            SELECT @@IDENTITY;",
            connection, transaction)
        With cmdSave.Parameters
            .AddWithValue("appId", Master.app.id)
            .Add(New SqlParameter("StartDate", SqlDbType.VarChar))
            .Add(New SqlParameter("EndDate", SqlDbType.VarChar))
            .Add(New SqlParameter("Comments", SqlDbType.VarChar))
        End With

        For Each item As RepeaterItem In rptUnemp.Items
            Dim hidId As HiddenField = item.FindControl("hidUnempId")
            Dim txtStartDate As TextBox = item.FindControl("txtStartDate")
            Dim txtEndDate As TextBox = item.FindControl("txtEndDate")
            Dim txtComments As TextBox = item.FindControl("txtComments")

            cmdSave.Parameters("StartDate").Value = Logic.Conversion.ToDate(txtStartDate.Text).Clip()
            cmdSave.Parameters("EndDate").Value = Logic.Conversion.ToDate(txtEndDate.Text).Clip()
            cmdSave.Parameters("Comments").Value = txtComments.Text

            hidId.Value = cmdSave.ExecuteScalar()
        Next

    End Sub

    Private Sub _SaveDocument(connection As SqlConnection, transaction As SqlTransaction)
        Dim ReportDataSet As New dsAppDrivingExperience
        Dim ReportTableAdapter As New TransactionalAppDrivingExperienceTableAdapter
        ReportTableAdapter.SetConnection(connection, transaction)
        ReportTableAdapter.Fill(ReportDataSet.AppDrivingExperienceDataTable, Master.app.id)

        Using Report As New crptAppDrivingExperience
            Report.SetDataSource(ReportDataSet)
            Dim rawData = Reporting.StreamToByteArray(Report)

            Dim cmdSave = "
                UPDATE web_DriverApplicationPdf SET pageTitle=@pageTitle, pdfData=@pdfData, pdfDataSize=@pdfDataSize
                WHERE appId=@appId AND pageFileName=@pageFileName;
                IF @@ROWCOUNT = 0 BEGIN
                    INSERT INTO web_DriverApplicationPdf (appId, pageTitle, pageFileName, pdfData, pdfDataSize)
                    VALUES (@appId, @pageTitle, @pageFileName, @pdfData, @pdfDataSize);
                END"
            Dim cmd As New SqlCommand(cmdSave, connection, transaction)
            cmd.Parameters.AddWithValue("appId", Master.app.id)
            cmd.Parameters.AddWithValue("pageTitle", Master.CurrentTitle)
            cmd.Parameters.AddWithValue("pageFileName", Master.CurrentPage)
            cmd.Parameters.AddWithValue("pdfData", rawData)
            cmd.Parameters.AddWithValue("pdfDataSize", rawData.Length)
            cmd.ExecuteNonQuery()
        End Using
    End Sub

#End Region

#Region "Other internals"


    Private Function _HasEnteredLastUnemp() As Boolean
        Dim count = rptUnemp.Items.Count
        If count = 0 Then
            Return True
        Else
            Dim item As RepeaterItem = rptUnemp.Items(count - 1)
            Dim txtStartDate As TextBox = item.FindControl("txtStartDate")
            Return txtStartDate.Text.Length > 0
        End If
    End Function

    Private Function _HasVisited() As Boolean
        Using connection As New SqlConnection(Logic.Database.ConnectionString)
            connection.Open()
            Dim cmd As New SqlCommand(
                "SELECT hasHadUnemp FROM web_DriverApplication WHERE id=@appId",
                connection)
            cmd.Parameters.AddWithValue("appId", Master.app.id)
            Return TypeOf cmd.ExecuteScalar() IsNot DBNull
        End Using
    End Function


    Private Sub _RemoveUnemp(itemId As Integer)
        Using connection As New SqlConnection(Logic.Database.ConnectionString)
            connection.Open()
            Dim cmd As New SqlCommand(
                "DELETE FROM web_DriverApplicationUnemployment WHERE id=@itemId",
                connection)
            cmd.Parameters.AddWithValue("itemId", itemId)
            cmd.ExecuteNonQuery()
        End Using
    End Sub

#End Region

End Class